Send gcode via ESP32 to Duet wifi.

AverageUser

Is it possible to send gcode from a ESP32 Controller to the Duet Wifi? I need a little kickstart here becuase I dont know where to begin. Thx a lot for your help.

A Former User

you can enable telnet and send it over wifi or connect to the paneldue serial port. there are a few posts on the forum that show how to do it.

AverageUser

Yeah I would like to send it over wifi, but with an ESP32. And that is the problem. I dont know where to start. A simple example would save my life ...

A Former User

there are examples in the arduino ide even
https://github.com/espressif/arduino-esp32/blob/master/libraries/WiFi/examples/WiFiClientBasic/WiFiClientBasic.ino

AverageUser

Ohh I know how to make http POST/GET requests with the wifi.h. But how do i channel it to the duet wifi? Do i have to type in the IP-Address of the Duet wifi as the destination for the http request?!?

A Former User

Use the IP address of the Duet.

But instead of HTTP requests you can enable telnet and connect to the telnet port and send GCODE directly instead of dealing with the DWC API

A Former User

i just want a simple led to turn on, when i press a button on the esp32... and it has to be via wlan

in that case the easiest is probably to stick with HTTP towards the IP of your Duet.

first you'll need to set up means to turn your led on and off; by means of a fan output M106 or a gpio M42 (<- click links to learn more)

Then simply sent the HTTP request to run the GCODE needed to turn the LED on.

to use Fan2 output
client.print("GET /rr_gcode?gcode=M106%20P2%20S1 HTTP/1.0\n\n");
or to use M42 with the same Fan2 outut (but not as a fan)
client.print("GET /rr_gcode?gcode=M42%20P22%20S1 HTTP/1.0\n\n");

AverageUser

Thank you very much!!!!

A Former User

simple ESP32 code to send g-code to duet

#include <WiFi.h>
#include <WiFiClient.h>
#include <ESPmDNS.h>


const int led = 5;
const char* ssid     = "ccc";
const char* password = "pass";

//const char* host = "192.168.1.115";
const char* host = "ender5.local.lan";
const int port = 23;
int l = 0;
int potValue = 0;

WiFiClient client;

int sendGcode(char * gcode){
    unsigned long timeout;
    int ret;

    ret = 1;
    
    client.print( String(gcode) + "\r\n" );
    timeout = millis();
    while (client.available() == 0) {
        if (millis() - timeout > 5000) break;
    }
    
    while(client.available()) {
        String line = client.readStringUntil('\r');
        Serial.print(line);
        if (line.startsWith("ok")) ret = 0;
        if (line.startsWith("\nok")) ret = 0;
        if (line.startsWith("\r\nok")) ret = 0;
    }
      
    return(ret);
}




void setup()
{
    pinMode(led, OUTPUT);
    digitalWrite(led, 0);
    Serial.begin(115200);
    delay(10);
    Serial.print("Connecting to ");
    Serial.println(ssid);

    WiFi.config(INADDR_NONE, INADDR_NONE, INADDR_NONE);
    WiFi.mode(WIFI_AP);
    if (MDNS.begin("pendantDue")) {
      Serial.println("MDNS responder started");
    }    
    WiFi.begin(ssid, password);
    while (WiFi.status() != WL_CONNECTED) {
        delay(500);
        Serial.print(".");
    }
    
    Serial.println("WiFi connected");
    Serial.print("IP address: ");
    Serial.println(WiFi.localIP());

    delay(1000);

    Serial.print("connecting to ");
    Serial.print(host);
    Serial.print(":");
    Serial.println(port);

    if (!client.connect(host, port)) {
        Serial.println("connection failed");
        while(1){
          digitalWrite(led, 0);
          delay(500);
          digitalWrite(led, 1);
          delay(500);
        }
        return;
    }
    
    Serial.print("CONNECTED to ");
    Serial.print(host);
    Serial.print(":");
    Serial.println(port);
}


void loop()
{
    delay(5000);
    sendGcode("M115");
}

AverageUser

@smece thx a lot.. that really saves me from wandering through github and places in the internet where my mind is not suited for. ^^ (smece-- funny name. means garbage in croatian language)

A Former User

@flipil said in Send gcode via ESP32 to Duet wifi.:

smece-- funny name. means garbage in croatian language)

znači i kod nas na istoku

thx a lot.. that really saves me from wandering

you are welcome, I started making a pendant for duet with esp32 so that's the initial test how to talk to it

note that if you don't close the connection client.stop(); it can "block" as it looks like duet is listening only with one or two threads ... you might want to change to open connection to send gcode and immediately close if you don't plan to send many commads